Assassins - Ultimate CD Games Collection 2/Assassins 2 - Ultimate Games No. 2 (1995)(Weird Science)[!][Amiga-CD32-CDTV].iso/arcade/boing_3/boingvs3.amos/boingvs3.amosSourceCode

AMOS Source Code | 1989-03-31 | 16KB | 716 lines

'
'             BOING!!!!!! Vs 3.0
'
'             WRITTEN BY SHAUN WATTERS
'
'             STARTED : 4/1/95

Dim MAP(19,47),SCOREFRAME(4),TIMEFRAME(2),LAZERY(5),LAZERX(5),LEVEL$(10),S(3)

Global MAP(),FILENAME$,LEVEL$,BX,BY,FRAME,SY,SCOREFRAME(),TIMEFRAME()
Global BOUNCE,MX_HEIGHT,HEIGHT,UP,YSPEED,JCOUNT,SCORE,LAZERY(),LAZERX()
Global LAZER,APPLES,XIT,XX,XY,EOL,LEVEL,LEVEL$(),TIME,DEAD
Global LIVES,S(),BLOCKCOUNT,BLOCKX,BLOCKY,B,BAX,BAY,FRAMECOUNT,FCOUNT
Global GTOS,SLEEP,SCOUNT,XITFRAME,TENFRAME,TX,TY,TENCOUNT,NEWLIFE


MAINLOOP


Procedure SETUP
   '
   '  SCREEN SETUP
   '
   Screen Open 0,320,256,8,Lowres
   DISKPRESENT
   Palette $0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0
   Hide
   LIVES=3
   If Length(7)=0 : Load "boing:samples.abk",7 : End If
  ' Track Load "df0:mod.late night shopping",8
  ' Track Loop On
  ' Track Play 8
  ' Track Loop On
   Sam Bank 7
   LEVEL$="df0:map1.map"
   If Length(1)=0 : Load "df0:boingsprites.abk" : End If
   Screen Open 2,320,512,8,Lowres : Rem FOREGROUND
   Flash Off
   Palette $0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0

   If Length(6)=0
      Load Iff "df0:waterfall.iff",0
      Palette $0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0
      Spack 0 To 6
   Else
      Unpack 6 To 0
      Palette $0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0
   End If

   Screen Open 1,320,512,8,Lowres
   Flash Off : Curs Off : Cls 0
   Palette $0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0
   Screen Copy 0,0,0,320,256 To 1,0,0
   Screen Copy 0,0,0,320,256 To 1,0,256
   Screen 0 : Cls 0
   If Length(10)=0
      Load Iff "df0:boingtitle.iff",0
      Spack 0 To 10
      Screen Close 0
   End If
   Unpack 10 To 0
   Screen Copy 0,0,0,320,256 To 2,0,0
   Load Iff "df0:boingtitle2.iff",0
   Screen Copy 0,0,0,320,256 To 2,0,256
   Screen Close 0

   Wait Vbl : Dual Playfield 2,1 : Wait Vbl

   Set Rainbow 0,15,32,"","",""

   For C=0 To 14
      Read CLR
      Rain(0,C*2)=CLR
      Rain(0,(C*2)+1)=CLR
   Next C

   For LC=1 To 19
      For LC1=1 To 47
         MAP(LC,LC1)=0
      Next LC1
   Next LC

   Screen Display 2,128,40,320,256 : View

   Screen 2 : Fade 2,$0,$F00,$D00,$B00,$900,$700,$500,$FFF,$0,$0,$0,$0,$0,$0,$0,$0,$A00,$600,$F00,$F5F,$FE0,$80,$0,$6,$8,$A
   For Y=30 To 0 Step -1
      Rainbow 0,0,154+Y,30-Y
      Wait Vbl : View
   Next Y

   Screen 2 : Limit Mouse : Screen To Front 2

   For LC=1 To 4 : SCOREFRAME(LC)=0 : Next LC
   For LC=1 To 2 : TIMEFRAME(LC)=9 : Next LC

   Data $F00,$E00,$D00,$C00,$B00,$A00,$900,$800,$802,$804,$806,$808,$80A,$80C,$80E

End Proc

Procedure LMAP
   DISKPRESENT
   Open In 1,FILENAME$
   For LC=0 To 19
      For LC2=0 To 47
         Input #1,MAP(LC,LC2)
      Next LC2
   Next LC
   Close 1
   DMAP
End Proc

Procedure BLOCKSETUP
  Screen Hide 0
  If Length(5)=0 : Load Iff "df0:blocks2.iff",0 : Spack 0 To 5
  Else Unpack 5 To 0 : End If
   Screen Hide 0
  N=1
  For Y=0 To 15
      For X=0 To 19
         Get Block N,X*16,Y*16,16,16 : Inc N
      Next X
  Next Y
  Screen Close 0
End Proc

Procedure DMAP
   Screen 2
   Cls 0
   Screen Hide 2
   X=0
   Y=0
   APPLES=0
   COUNT=1
   For LC=0 To 19
      For LC2=0 To 47
         If MAP(LC,LC2)=2 : Inc APPLES : End If
         If MAP(LC,LC2)>0

             If MAP(LC,LC2)=181 or MAP(LC,LC2)=161

                  If MAP(LC,LC2)=161 : XX=LC : XY=LC2 : Put Block 1,X,Y
                  Else Put Block 1,X,Y : End If

             Else Put Block MAP(LC,LC2),X,Y : End If
         End If

         If MAP(LC,LC2)=107 or MAP(LC,LC2)=108
            LAZERY(COUNT)=LC2
            LAZERX(COUNT)=LC
            Inc COUNT
            Inc LAZER
         End If
         Y=Y+16
      Next LC2
      Y=0
      X=X+16
   Next LC
End Proc

Procedure COPPERSETUP

  Set Rainbow 0,15,32,"","",""

  For C=0 To 14
      Read CLR
      Rain(0,C*2)=CLR
      Rain(0,(C*2)+1)=CLR
  Next C

  For Y=30 To 0 Step -1
      Rainbow 0,0,154+Y,30-Y
      Wait Vbl : View
  Next Y

  Data $FA0,$E80,$D40,$C20,$B00,$A00,$900,$800,$802,$804,$806,$828,$84A,$88C,$8AE
End Proc

Procedure SETUPVARS
   XITFRAME=61
   GTOS=0
   SLEEP=0
   SCOUNT=0
   BLOCKCOUNT=0
   FCOUNT=0
   FRAMECOUNT=0
   BX=288
   BY=632
   FRAME=2
   SY=512
   BOUNCE=-6
   HEIGHT=0
   UP=0
   YSPEED=0
   LAZER=0
   LEVEL=1
   TIME=75
   DEAD=0
   S(1)=240
   S(2)=245
   S(3)=250
   LEVEL$(1)="df0:1.map"
   LEVEL$(2)="df0:2.map"
   LEVEL$(3)="df0:3.map"
   LEVEL$(4)="df0:4.map"
   LEVEL$(5)="df0:5.map"
   LEVEL$(6)="df0:6.map"
End Proc

Procedure LEVELINIT
   Screen Offset 2,0,SY
   Screen Offset 1,0,SY/2
End Proc

Procedure DISPLAYSPRITES

   Sprite 6,BX+128,BY+44-SY,FRAME

   Sprite 10,132,50,SCOREFRAME(1)+5
   Sprite 11,132,62,SCOREFRAME(2)+5
   Sprite 12,132,74,SCOREFRAME(3)+5
   Sprite 13,132,86,SCOREFRAME(4)+5

   Sprite 17,132,226,16
   Sprite 14,132,238,TIMEFRAME(1)+5
   Sprite 15,132,250,TIMEFRAME(2)+5

   Sprite 18,132,276,15
   Sprite 19,132,288,LIVES+5

   If TENFRAME>0 : Bob 2,TX,TY,TENFRAME : End If

End Proc

Procedure BEGINING
   Screen Show 2
Do
   For LC=0 To 245
      If Fire(1) : Pop Proc : End If
      Wait Vbl
   Next LC

   For LC=0 To 245
      Screen Offset 2,0,Y/2
      Screen Offset 1,0,256-(Y/2)
      Y=Y+2
      If Fire(1) : Pop Proc : End If
      Wait Vbl
   Next LC

   For LC=0 To 245
      If Fire(1) : Pop Proc : End If
      Wait Vbl
   Next LC

   For LC=0 To 245
      Screen Offset 2,0,Y/2
      Screen Offset 1,0,256-(Y/2)
      Y=Y-2
      If Fire(1) : Pop Proc : End If
      Wait Vbl
   Next LC

Loop
End Proc

Procedure DISKPRESENT
   F$="boing:"
   If Exist(F$) : Pop Proc : End If
   Screen Open 0,320,200,8,Lowres
   Unpack 5 To 0
   Cls 0
   Put Block 281,155,95
   Put Block 282,171,95
   Put Block 301,155,111
   Put Block 302,171,111
   Repeat
      Palette $0,$A0,$FF0,$F00,$A00,$A9F,$45C,$4A
      Wait 10
      Palette $0,$0,$0,$0,$0,$0,$0,$0
      Wait 10
   Until Exist(F$)
   Screen Close 0
End Proc

Procedure SF1
   DISKPRESENT
   Erase 8
   Rainbow Del
   XIT=0
   EOL=0
   Fade 2 : Wait 30
   Screen 2
   Screen Hide 2
   Screen Close 1
   Screen Close 2
   Screen Open 2,320,768,8,Lowres
   Curs Off : Flash Off : Cls 0
   Palette $0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0
   Screen Open 1,320,512,8,Lowres
   Screen 1 : Cls 0
   Wait Vbl : Dual Playfield 2,1 : Wait Vbl
   Screen 2
   Screen Hide 2
   Load Iff "df0:back3.iff",0 : Screen 0
   Palette $0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0,$0
   Screen Copy 0,0,0,320,256 To 1,0,1
   Screen Copy 0,0,0,320,256 To 1,0,256
   Screen Close 0
   Screen 2 : Cls 0
   Screen Display 2,128,45,320,256
   FILENAME$=LEVEL$(LEVEL)
   LMAP
   COPPERSETUP
   Palette $0,$B0,$FF0,$F00,$A00,$A9F,$45B,$4A,$0,$222,$333,$444,$555,$666,$777,$FF0,$0,$FFF,$EBB,$888,$444,$0,$E00,$303,$105,$3F3,$8F8,$6F,$4D,$2A,$18,$6
   Screen Show 2
   GREADY
End Proc

Procedure MAIN
'
'    !!!!!!GOING UP!!!!!!!
'
   Dec TIME
   If TIME=0 : CALCTIME : TIME=75 : End If

   If UP=1

   If MAP(BX/16,(BY-8)/16)>106 and MAP(BX/16,(BY-8)/16)<121 : LOSELIFE : End If

      If YSPEED<0
         If SLEEP=0 : FRAME=34+FRAMECOUNT : End If
         If MAP(BX/16,(BY-2)/16)<61 and MAP((BX+15)/16,(BY-2)/16)<61
            BY=BY+YSPEED
            Inc JCOUNT : If JCOUNT=3 : JCOUNT=0 : Inc YSPEED : End If
         Else
            YSPEED=-YSPEED
            Inc BOUNCE
            UP=0
         End If
      End If

      If YSPEED=0
         If MAP(BX/16,(BY+16)/16)<61 or MAP((BX+15)/16,(BY+16)/16)<61
            Inc BOUNCE : UP=0
         End If
      End If

'
'   !!!!!GOING DOWN!!!!!
'
   Else

      Do
         If MAP(BX/16,(BY+16)/16)>60 or MAP((BX+15)/16,(BY+16)/16)>60
            If BOUNCE<0 : YSPEED=BOUNCE : Else YSPEED=-2 : End If
            UP=1 : Exit
         End If

         If SLEEP=0 : FRAME=30+FRAMECOUNT : End If
         If BOUNCE=0 and Fire(1) : YSPEED=2 : BOUNCE=-3 : End If
         BY=BY+YSPEED
         Inc JCOUNT : If JCOUNT=3 : JCOUNT=0 : If YSPEED<8 : Inc YSPEED : End If : End If
         Exit
      Loop

      If(MAP((BX)/16,(BY+16)/16)=182 and MAP((BX+15)/16,(BY+16)/16)=182) and YSPEED=0 : Sam Play 4,3 : YSPEED=-8 : B=1 : BOUNCE=YSPEED : End If
      If(MAP((BX)/16,(BY+16)/16)=181 or MAP((BX+15)/16,(BY+16)/16)=181) and YSPEED=0 : Sam Play 4,3 : YSPEED=-8 : BOUNCE=YSPEED : End If
   End If


   If Jleft(1)
      GTOS=0
      SLEEP=0
      If MAP((BX-2)/16,BY/16)>106 and MAP((BX-2)/16,BY/16)<121 : LOSELIFE : End If
      If XIT=1 and MAP((BX-2)/16,BY/16)=161 : EOL=1 : End If
      If MAP((BX-2)/16,BY/16)=2 : PICKUPSLEFT : End If
      If SLEEP=0 : FRAME=38+FRAMECOUNT : End If
      If MAP((BX-2)/16,BY/16)<61 : BX=BX-2 : End If
   End If

   If Jright(1)
      GTOS=0
      SLEEP=0
      If XIT=1 and MAP((BX+17)/16,BY/16)=161 : EOL=1 : End If
      If MAP((BX+17)/16,BY/16)>106 and MAP((BX+17)/16,BY/16)<121 : LOSELIFE : End If
      If MAP((BX+17)/16,BY/16)=2 : PICKUPSRIGHT : End If
      If SLEEP=0 : FRAME=42+FRAMECOUNT : End If
      If MAP((BX+17)/16,BY/16)<61 : BX=BX+2 : End If
   End If

   If MAP(BX/16,(BY+16)/16)=141
      BLOCKCOUNT=5
      BLOCKX=BX/16 : BLOCKX=BLOCKX*16 : Rem DISAPEARING BLOCKS
      BLOCKY=(BY+16)/16 : BLOCKY=BLOCKY*16
   End If

    If MAP((BX+8)/16,(BY+16)/16)>106 and MAP((BX+8)/16,(BY+16)/16)<115 : LOSELIFE : End If

    If MAP((BX+8)/16,(BY-2)/16)>106 and MAP((BX+8)/16,(BY-2)/16)<115 : LOSELIFE : End If


   If BLOCKCOUNT>1 : Dec BLOCKCOUNT : End If

   If BLOCKCOUNT=1
            Sam Play 4,4
            Put Block 21,BLOCKX,BLOCKY
            MAP(BLOCKX/16,BLOCKY/16)=21
            BLOCKCOUNT=0
   End If

   If Key State(69) : DEAD=1 : End If
   If SCORE=1000 and NEWLIFE=0 : Inc LIVES : NEWLIFE=1 : End If

   If MAP(BX/16,(BY+16)/16)=182 and MAP((BX+15)/16,(BY+16)/16)=182 : Sam Play 4,3 : B=1 : If BOUNCE>-12 : Dec BOUNCE : End If : End If : Rem lands on trampoline
   If MAP(BX/16,(BY+16)/16)=181 or MAP((BX+15)/16,(BY+16)/16)=181 : Sam Play 4,3 : If BOUNCE>-12 : Dec BOUNCE : End If : End If : Rem lands on trampoline

   If MAP(BX/16,(BY+16)/16)=2 : PICKUPSDOWN : End If

   If MAP(BX/16,(BY-2)/16)=2 : PICKUPUP : End If

   If MAP((BX+8)/16,(BY+16)/16)>182 and MAP((BX+8)/16,(BY+16)/16)<186 : OPENDOOR : End If

   If MAP(BX/16,(BY+16)/16)>106 and MAP(BX/16,(BY+16)/16)<115 : LOSELIFE : End If

    SPRING

   If XIT=0 and APPLES=0
       XIT=1
   End If

   If XIT=1 : Bob 1,XX*16,XY*16,XITFRAME : End If

   Inc XITFRAME : If XITFRAME=67 : XITFRAME=61 : End If

   If XIT=1 and MAP(BX/16,(BY+8)/16)=161 : LEAVE : EOL=1 : End If

   SY=BY-120
   If SY<0 : SY=0 : End If
   If SY>512 : SY=512 : End If
   If DEAD=1 : Sam Play 4,1 : End If
   Inc FCOUNT
   If FCOUNT=4 : Inc FRAMECOUNT : FCOUNT=0 : End If
   If FRAMECOUNT=4 : FRAMECOUNT=0 : End If
   If SLEEP=0 : Inc GTOS : End If
   If GTOS=240 : SLEEP=1 : GTOS=0 : FRAME=51 : End If
   If SLEEP=1 : Inc SCOUNT : End If
   If SCOUNT=5 : Inc FRAME : SCOUNT=0 : End If
   If FRAME=61 : FRAME=57 : End If
   If TENFRAME>0 : Inc TENCOUNT : End If
   If TENCOUNT=2 : Inc TENFRAME : TENCOUNT=0 : End If
   If TENFRAME=71 : TENFRAME=0 : Bob Off : End If
End Proc

Procedure GREADY

   Screen Offset 2,0,SY
   Screen Offset 1,0,SY/2
   X1=448 : X2=488

   Repeat
      Sprite 8,X1,160,17 : If X1>288 : Add X1,-4 : End If
      Sprite 9,X2,180,18 : Add X2,-4
      Wait Vbl
   Until X2<288

   Sprite 10,295,200,LEVEL+5

   For LC=1 To 50 : Wait Vbl : Next LC

   Sprite Off 10

   Repeat
      Sprite 8,X1,160,17 : Add X1,-8
      Wait Vbl
   Until X1<248
   Repeat
      Sprite 8,X1,160,17 : Add X1,-8
      Sprite 9,X2,180,18 : Add X2,-8
      Wait Vbl
   Until X2<128

Sprite Off
End Proc

Procedure LOSELIFE
   Sam Play 4,2
   For LC=19 To 29
      Sprite 6,BX+128,BY+44-SY,LC
      If LC<23 : Wait 2 : End If
      Wait 3
      Wait Vbl
   Next LC
   BX=288
   BY=600
   FRAME=2
   SY=512
   BOUNCE=-6
   HEIGHT=0
   UP=0
   YSPEED=0
   Dec LIVES
   If LIVES=0 : DEAD=1 : End If
End Proc

Procedure LEAVE
   L=0
   For LC=46 To 50
      Sprite 6,BX+128,BY+44-SY,LC
      Wait 8
      If LC=50 and L=0 : LC=46 : L=1 : End If
   Next LC
End Proc

Procedure PICKUPSDOWN
   Sam Play 4,6
   Y=(BY+16)/16
   Y=Y*16
   X=BX/16
   X=X*16
   SCORE=SCORE+10
   Put Block 1,X,Y
   MAP(BX/16,(BY+16)/16)=1
   Dec APPLES
   CALCSCORE
   TEN
End Proc

Procedure SPRING
   If B=0 : Pop Proc : End If
   If B=1
      BAY=(BY+16)/16
      BAY=BAY*16
      BAX=BX/16
      BAX=BAX*16
   End If

  If B<6
      Put Block B+200,BAX,BAY
      Inc B
  Else B=0 : End If
End Proc

Procedure PICKUPUP
   Sam Play 4,6
   Y=(BY-2)/16
   Y=Y*16
   X=BX/16
   X=X*16
   SCORE=SCORE+10
   Put Block 1,X,Y
   MAP(BX/16,(BY-2)/16)=1
   Dec APPLES
   CALCSCORE
   TEN
End Proc

Procedure PICKUPSLEFT
   Sam Play 4,6
   X=(BX-2)/16
   X=X*16
   Y=BY/16
   Y=Y*16
   SCORE=SCORE+10
   Put Block 1,X,Y
   MAP((BX-2)/16,BY/16)=1
   Dec APPLES
   CALCSCORE
   TEN
End Proc

Procedure PICKUPSRIGHT
   Sam Play 4,6
   X=(BX+17)/16
   X=X*16
   Y=BY/16
   Y=Y*16
   SCORE=SCORE+10
   Put Block 1,X,Y
   MAP((BX+17)/16,BY/16)=1
   Dec APPLES
   CALCSCORE
   TEN
End Proc

Procedure OPENDOOR
      Sam Play 4,5
      On(MAP(BX/16,(BY+16)/16))-182 Gosub A,B,C,D
   Pop Proc

   A:
      X=BX/16
      X=X*16
      Y=(BY+16)/16
      Y=Y*16
      Put Block MAP(BX/16,(BY+16)/16)-142,X,Y
      Put Block 21,LAZERX(1)*16,LAZERY(1)*16
      MAP(LAZERX(1),LAZERY(1))=1
      MAP(LAZERX(1),LAZERY(1)+1)=1
      MAP(LAZERX(1),LAZERY(1)-1)=1
   Return

  B:
      X=BX/16
      X=X*16
      Y=(BY+16)/16
      Y=Y*16
      Put Block MAP(BX/16,(BY+16)/16)-142,X,Y
      Put Block 1,LAZERX(2)*16,LAZERY(2)*16
      MAP(LAZERX(2),LAZERY(2))=1
      MAP(LAZERX(2),LAZERY(2)+1)=1
      MAP(LAZERX(2),LAZERY(2)-1)=1
   Return

  C:
      X=BX/16
      X=X*16
      Y=(BY+16)/16
      Y=Y*16
      Put Block MAP(BX/16,(BY+16)/16)-142,X,Y
      Put Block 1,LAZERX(3)*16,LAZERY(3)*16
      MAP(LAZERX(3),LAZERY(3))=1
      MAP(LAZERX(3),LAZERY(3)+1)=1
      MAP(LAZERX(3),LAZERY(3)-1)=1
   Return

  D:
      X=BX/16
      X=X*16
      Y=(BY+16)/16
      Y=Y*16
      Put Block MAP(BX/16,(BY+16)/16)-142,X,Y
      Put Block 1,LAZERX(4)*16,LAZERY(4)*16
      MAP(LAZERX(4),LAZERY(4))=1
      MAP(LAZERX(4),LAZERY(4)+1)=1
      MAP(LAZERX(4),LAZERY(4)-1)=1
   Return
End Proc

Procedure CALCTIME
   If TIMEFRAME(2)>-1 : Dec TIMEFRAME(2) : End If
   If TIMEFRAME(2)=-1 : TIMEFRAME(2)=9 : Dec TIMEFRAME(1) : End If
   If TIMEFRAME(2)=0 and TIMEFRAME(1)=0 : DEAD=1 : End If
End Proc

Procedure CALCSCORE
NEWLIFE=0
If SCOREFRAME(2)=9 and SCOREFRAME(3)=9 : Inc SCOREFRAME(1) : SCOREFRAME(2)=0 : SCOREFRAME(3)=0 : End If
If SCOREFRAME(3)<10 : Inc SCOREFRAME(3) : End If
If SCOREFRAME(3)=10 and SCOREFRAME(2)<9 : Inc SCOREFRAME(2) : SCOREFRAME(3)=0 : End If
If SCOREFRAME(1)=9 and SCOREFRAME(2)=9 and SCOREFRAME(3)=9
                              For LC=1 To 4
                                 SCOREFRAME(LC)=0
                              Next LC
End If
End Proc

Procedure SCRSCN
   Screen Offset 2,0,SY
   Screen Offset 1,0,SY/2
End Proc

Procedure NXTLEVEL
   Sprite Off
   Rainbow Del
   Screen 1 : Fade 2 : Wait 30
   Screen 2 : Fade 2 : Wait 30
   Screen Hide 2
   BX=288
   BY=600
   FRAME=2
   SY=512
   BOUNCE=-6
   HEIGHT=0
   UP=0
   YSPEED=0
   TIMEFRAME(1)=9
   TIMEFRAME(2)=9
   Inc LEVEL
   If LEVEL=7 : LEVEL=0 : End If
   SF1
   LEVELINIT
End Proc

Procedure MAINLOOP
BLOCKSETUP
Do
   SETUP
   SETUPVARS
   BEGINING
   Track Stop
   Erase 8
   SF1
   DISPLAYSPRITES
   LEVELINIT
   Repeat
      MAIN
      DISPLAYSPRITES
      SCRSCN
      Wait Vbl
      If EOL : LEAVE : NXTLEVEL : End If
   Until DEAD=1
   Erase 6 : Erase 10
   Fade 2 : Wait 30
   Rainbow Del
   Screen Open 0,320,256,8,Lowres
   Flash Off : Curs Off : Cls 0
   Sprite Off
Loop
End Proc

Procedure TEN
   TENFRAME=67
   TX=BX
   TY=BY-16
   TENCOUNT=0
End Proc